mirror of
https://github.com/denoland/deno.git
synced 2024-11-26 16:09:27 -05:00
339 lines
9.6 KiB
Text
339 lines
9.6 KiB
Text
declare_args() {
|
|
# Absolute path of rust build files.
|
|
rust_build = "//build_extra/rust/"
|
|
|
|
# Wrapper executable for rustc invocations. This can be used for a caching
|
|
# utility, e.g. sccache.
|
|
rustc_wrapper = ""
|
|
|
|
# treat the warnings in rust files as errors
|
|
rust_treat_warnings_as_errors = true
|
|
}
|
|
|
|
if (is_win) {
|
|
executable_suffix = ".exe"
|
|
} else {
|
|
executable_suffix = ""
|
|
}
|
|
|
|
# To simplify transitive dependency management with gn, we build all rust
|
|
# crates into the same directory. We need to be careful not to have crates
|
|
# with the same name.
|
|
out_dir = "$root_out_dir/rust_crates"
|
|
|
|
# The official way of building Rust executables is to to let rustc do the
|
|
# linking. However, we'd prefer to leave it in the hands of gn/ninja:
|
|
# * It allows us to use source sets.
|
|
# * It allows us to use the bundled lld that Chromium and V8 use.
|
|
# * We have more control over build flags.
|
|
# * To sidestep rustc weirdness (e.g. on Windows, it always links with the
|
|
# release C runtime library, even for debug builds).
|
|
#
|
|
# The `get_rust_ldflags` tool outputs the linker flags that are needed to
|
|
# successfully link rustc object code into an executable.
|
|
# We generate two sets of ldflags:
|
|
# `rust_bin_ldflags`: Used for rust_executable targets.
|
|
# `rust_test_ldflags`: Used for rust_test targets; includes the test harness.
|
|
#
|
|
# The tool works by compiling and linking something with rustc, and analyzing
|
|
# the arguments it passes to the system linker. That's what dummy.rs is for.
|
|
dummy_rs_path = rebase_path("dummy.rs", root_build_dir)
|
|
rust_bin_ldflags =
|
|
exec_script("get_rust_ldflags.py", [ dummy_rs_path ], "list lines")
|
|
rust_test_ldflags = exec_script("get_rust_ldflags.py",
|
|
[
|
|
dummy_rs_path,
|
|
"--test",
|
|
],
|
|
"list lines")
|
|
|
|
template("run_rustc") {
|
|
action(target_name) {
|
|
assert(defined(invoker.source_root), "Must specify source_root")
|
|
forward_variables_from(invoker,
|
|
[
|
|
"crate_name",
|
|
"crate_type",
|
|
"crate_version",
|
|
"deps",
|
|
"extern_infos",
|
|
"features",
|
|
"is_test",
|
|
"source_root",
|
|
"testonly",
|
|
"treat_warnings_as_errors",
|
|
])
|
|
if (!defined(crate_name)) {
|
|
crate_name = target_name
|
|
}
|
|
if (!defined(is_test)) {
|
|
is_test = false
|
|
}
|
|
if (!defined(treat_warnings_as_errors)) {
|
|
# Use global setting if not explicitly specified for this target.
|
|
treat_warnings_as_errors = rust_treat_warnings_as_errors
|
|
}
|
|
|
|
if (!defined(crate_version)) {
|
|
# If there is only a single version of this crate in our tree, there's no
|
|
# need to set the crate metadata and add a suffix to the file name.
|
|
metadata = ""
|
|
crate_suffix = ""
|
|
} else {
|
|
# Rustc blows up if a target (directly or indirectly) depends on two+
|
|
# crates that have the same name *and* the same metadata, so we use the
|
|
# version number to ensure they have unique metadata.
|
|
metadata = crate_version
|
|
|
|
# In our build setup, all crates are built in the same directory. To avoid
|
|
# file name conflicts between when multiple versions of the same crate are
|
|
# built, add a unique suffix to output file names.
|
|
#
|
|
# Unfortunately the version number as such can't be used directly:
|
|
# everything after the first dot (.) is thrown away by rust, so in case of
|
|
# foo-0.2 vs foo-0.3 only the first '0' would be used, and conflicts would
|
|
# still occur. Therefore we use a hash of the version number instead.
|
|
crate_suffix = exec_script("//tools/sha256sum.py",
|
|
[
|
|
"--input=$crate_version",
|
|
"--format=-%.8s",
|
|
],
|
|
"trim string")
|
|
}
|
|
|
|
if (crate_type == "bin") {
|
|
output_file = "$out_dir/$crate_name$crate_suffix.o"
|
|
emit_type = "obj"
|
|
} else if (crate_type == "rlib") {
|
|
output_file = "$out_dir/lib$crate_name$crate_suffix.rlib"
|
|
emit_type = "link"
|
|
}
|
|
|
|
script = "//third_party/v8/tools/run.py"
|
|
sources = [
|
|
source_root,
|
|
]
|
|
outputs = [
|
|
output_file,
|
|
]
|
|
depfile = "$out_dir/$crate_name$crate_suffix.d"
|
|
|
|
if (rustc_wrapper != "") {
|
|
args = [ rustc_wrapper ]
|
|
} else {
|
|
args = []
|
|
}
|
|
|
|
args += [
|
|
"rustc",
|
|
rebase_path(source_root, root_build_dir),
|
|
"--crate-name=$crate_name",
|
|
"--crate-type=$crate_type",
|
|
"--emit=$emit_type,dep-info",
|
|
"--out-dir=" + rebase_path(out_dir, root_build_dir),
|
|
|
|
# This is to disambiguate multiple versions of the same crate.
|
|
"-Cextra-filename=$crate_suffix",
|
|
"-Cmetadata=$metadata",
|
|
|
|
# This is needed for transitive dependencies.
|
|
"-L",
|
|
"dependency=" + rebase_path(out_dir, root_build_dir),
|
|
|
|
# Use colorful output even if stdout is redirected and not a tty.
|
|
"--color=always",
|
|
]
|
|
|
|
if (treat_warnings_as_errors) {
|
|
args += [ "-Dwarnings" ]
|
|
}
|
|
|
|
if (is_debug) {
|
|
args += [ "-g" ]
|
|
}
|
|
|
|
if (is_official_build) {
|
|
args += [ "-O" ]
|
|
}
|
|
|
|
if (is_test) {
|
|
args += [ "--test" ]
|
|
}
|
|
|
|
if (defined(features)) {
|
|
foreach(f, features) {
|
|
args += [
|
|
"--cfg",
|
|
"feature=\"" + f + "\"",
|
|
]
|
|
}
|
|
}
|
|
|
|
if (defined(invoker.args)) {
|
|
args += invoker.args
|
|
}
|
|
|
|
if (!defined(deps)) {
|
|
deps = []
|
|
}
|
|
|
|
inputs = []
|
|
|
|
# Build the list of '--extern' arguments from the 'extern_infos' array.
|
|
foreach(info, extern_infos) {
|
|
rlib = "$out_dir/lib${info.crate_name}${info.crate_suffix}.rlib"
|
|
args += [
|
|
"--extern",
|
|
info.crate_name + "=" + rebase_path(rlib, root_build_dir),
|
|
]
|
|
inputs += [ rlib ]
|
|
deps += [
|
|
"${info.label}_rustc",
|
|
info.label,
|
|
]
|
|
}
|
|
}
|
|
}
|
|
|
|
template("rust_crate") {
|
|
rustc_name = target_name + "_rustc"
|
|
rustc_label = ":" + rustc_name
|
|
config_name = target_name + "_config"
|
|
|
|
# Convert all 'extern' and 'extern_version' items to a single format.
|
|
extern_infos = []
|
|
if (defined(invoker.extern)) {
|
|
foreach(label, invoker.extern) {
|
|
extern_infos += [
|
|
{
|
|
label = label
|
|
crate_name = get_label_info(label, "name")
|
|
crate_suffix = ""
|
|
},
|
|
]
|
|
}
|
|
}
|
|
if (defined(invoker.extern_version)) {
|
|
foreach(info, invoker.extern_version) {
|
|
extern_infos += [
|
|
{
|
|
forward_variables_from(info,
|
|
[
|
|
"label",
|
|
"crate_name",
|
|
"crate_version",
|
|
])
|
|
crate_suffix = exec_script("//tools/sha256sum.py",
|
|
[
|
|
"--input=$crate_version",
|
|
"--format=-%.8s",
|
|
],
|
|
"trim string")
|
|
},
|
|
]
|
|
}
|
|
}
|
|
|
|
forward_variables_from(invoker,
|
|
[
|
|
"crate_name",
|
|
"crate_type",
|
|
])
|
|
if (!defined(crate_name)) {
|
|
crate_name = target_name
|
|
}
|
|
if (!defined(crate_type)) {
|
|
crate_type = "rlib"
|
|
}
|
|
|
|
run_rustc(rustc_name) {
|
|
forward_variables_from(invoker,
|
|
[
|
|
"args",
|
|
"crate_version",
|
|
"deps",
|
|
"features",
|
|
"is_test",
|
|
"source_root",
|
|
"testonly",
|
|
"treat_warnings_as_errors",
|
|
])
|
|
}
|
|
|
|
crate_outputs = get_target_outputs(rustc_label)
|
|
crate_obj = crate_outputs[0]
|
|
|
|
config(config_name) {
|
|
lib_dirs = []
|
|
forward_variables_from(invoker, [ "libs" ])
|
|
if (!defined(libs)) {
|
|
libs = []
|
|
}
|
|
foreach(info, extern_infos) {
|
|
rlib = "$out_dir/lib${info.crate_name}${info.crate_suffix}.rlib"
|
|
libs += [ rlib ]
|
|
}
|
|
lib_dirs = [ out_dir ]
|
|
}
|
|
|
|
source_set(target_name) {
|
|
forward_variables_from(invoker,
|
|
[
|
|
"deps",
|
|
"libs",
|
|
"testonly",
|
|
])
|
|
if (!defined(deps)) {
|
|
deps = []
|
|
}
|
|
if (!defined(libs)) {
|
|
libs = []
|
|
}
|
|
libs += [ crate_obj ]
|
|
deps += [ rustc_label ]
|
|
all_dependent_configs = [ ":" + config_name ]
|
|
}
|
|
}
|
|
|
|
template("rust_executable") {
|
|
bin_name = target_name + "_bin"
|
|
bin_label = ":" + bin_name
|
|
|
|
rust_crate(bin_name) {
|
|
crate_type = "bin"
|
|
forward_variables_from(invoker, "*")
|
|
}
|
|
|
|
executable(target_name) {
|
|
forward_variables_from(invoker, "*")
|
|
|
|
if (defined(is_test) && is_test) {
|
|
ldflags = rust_test_ldflags
|
|
} else {
|
|
ldflags = rust_bin_ldflags
|
|
}
|
|
|
|
if (!defined(deps)) {
|
|
deps = []
|
|
}
|
|
|
|
deps += [ bin_label ]
|
|
|
|
if (defined(extern)) {
|
|
deps += extern
|
|
}
|
|
if (defined(extern_version)) {
|
|
foreach(info, extern_version) {
|
|
deps += [ info.label ]
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
template("rust_test") {
|
|
rust_executable(target_name) {
|
|
forward_variables_from(invoker, "*")
|
|
is_test = true
|
|
testonly = true
|
|
}
|
|
}
|